# -*- gnuplot -*-
#
# Create figs/gaussmixA.eps{,_t} for fig:GaussMix in "algorithms.tex".

# Copyright (c) 2005, 2007 Andrew Fraser
#
# This file is part of HMM_DS_Code.
#
# HMM_DS_Code is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# HMM_DS_Code is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
# 02111-1307, USA.
#

pi = 3.14159265359

alpha =  0.5
mu0   = -1.0
mu1   =  1.0

# From eq:GaussMix, here with x for x(t).
#
P_theta(x) =   (1.0 / sqrt (2.0 * pi))			\
	       * ((alpha * exp(-0.5 * (x - mu0)**2 ))	\
                  + ((1.0 - alpha)			\
                     * exp(-0.5 * (x - mu1)**2)))

P(x) = (1.0 / sqrt (2.0 * pi))			\
       * ((0.5 * exp(-0.5 * (x - 2.0)**2 ))	\
          + ((0.5) * exp(-0.5 * (x + 2.0)**2)))


set terminal epslatex monochrome dashed "normal" 9
set size 0.98,0.49
set output "`echo -n $GP_OUTPUT`"

set border 3
set key spacing 2.5

set format x ' '
unset xlabel
set xtics nomirror

set ytics 0.0,0.05,0.25
set format y '$%3.2f$'
set ytics nomirror

plot [-6:6]					\
     [-0.004:0.250]				\
     P_theta(x) title '\ptheta',		\
     P(x)       title '\px'

set output